1 REM KALEI5 : Caleidoscope
2 CLS:CLEAR:DEFINTA-Z:SCREEN,0
3 FORT=0TOVAL(RIGHT$(TIME$,2)):R=RND(1):NEXT
4 GOSUB20:X1(9)=R:GOSUB20:Y1(9)=R
5 GOSUB20:X2(9)=R:GOSUB20:Y2(9)=R
6 FORT=0TOVAL(RIGHT$(TIME$,2)):R=RND(1):NEXT
7 GOSUB22:A=R:GOSUB22:B=R
8 GOSUB22:C=R:GOSUB22:D=R
9 GOTO 31
10 REM Line
11 LINE(88+X1,Y1)-(88+X2,Y2),K
12 LINE(151-X1,Y1)-(151-X2,Y2),K
13 LINE(88+X1,63-Y1)-(88+X2,63-Y2),K
14 LINE(151-X1,63-Y1)-(151-X2,63-Y2),K
15 LINE(88+Y1,X1)-(88+Y2,X2),K
16 LINE(151-Y1,X1)-(151-Y2,X2),K
17 LINE(88+Y1,63-X1)-(88+Y2,63-X2),K
18 LINE(151-Y1,63-X1)-(151-Y2,63-X2),K
19 RETURN
20 R=RND(1)*64
21 RETURN
22 R=SGN(RND(1)-0.5):IFR=0GOTO22
23 RETURN
30 REM loop
31 FOR N=0 TO 9:P=N-1:IFP=-1THENP=9
32 X1=X1(N):Y1=Y1(N):X2=X2(N):Y2=Y2(N)
33 K=0:GOSUB11
34 X1(N)=X1(P)+A:IF(X1(N)>63 OR X1(N)<0) THEN X1(N)=X1(N)-2*A:A=-A
35 Y1(N)=Y1(P)+B:IF(Y1(N)>63 OR Y1(N)<0) THEN Y1(N)=Y1(N)-2*B:B=-B
36 X2(N)=X2(P)+C:IF(X2(N)>63 OR X2(N)<0) THEN X2(N)=X2(N)-2*C:C=-C
37 Y2(N)=Y2(P)+D:IF(Y2(N)>63 OR Y2(N)<0) THEN Y2(N)=Y2(N)-2*D:D=-D
38 X1=X1(N):Y1=Y1(N):X2=X2(N):Y2=Y2(N)
39 K=1:GOSUB11
40 NEXT
41 Q=Q+1:IFQ=5 THEN Q=0:GOTO7
42 GOTO 31